Занимательные задачи
методическая разработка по информатике и икт (9,10 класс) на тему

Занимательные задачи

'*************************************************************************

'*  GF_IMJ         Рисование  "плетенки" + мнимой спирали                *

'*  ------                                                               *

'*  Источник: С.В.Филичев "Занимательный Basic в задачах". Издат. ЭКОМ   *

'*  --------                                                             *

'*   Сентябрь 1999 г.                               Автор: Перчиц С.Н.   *

'*************************************************************************

'

pi = 3.14159

xc = 200

yc = 200

rb = 200

c = 12

SCREEN 12

                                                         'плетенка

du = pi / rb

dub = 2 * pi / 24

FOR ub = 0 TO 2 * pi STEP dub

   FOR ddub = 0 TO dub / 3 STEP dub / 20

      u = ub + ddub

      FOR r = 0 TO rb

         u = u + du

         x = r * COS(u)

         y = r * SIN(u)

         PSET (xc + x, yc + y), c

         PSET (xc + x, yc - y), c

      NEXT r

   NEXT ddub

NEXT ub

                                                         'мнимая спираль

r = 1

DO

   r = r * 1.19

   IF r > rb THEN EXIT DO

   FOR u = 0 TO 2 * pi STEP 1 / r

      rd = r + u * 10 - INT(u * 5) * 2

      x = rd * COS(u) + xc

      y = rd * SIN(u) + yc

      IF POINT(x, y) = c THEN PSET (x, y), c + 1 ELSE PSET (x, y), c + 2

   NEXT u

LOOP

'*************************************************************************

'*  GF_PL         Рисование  "плетенки"                                  *

'*  -----                                                                 *

'*  Источник: С.В.Филичев "Занимательный Basic в задачах". Издат. ЭКОМ   *

'*  --------                                                             *

'*   Август 1999 г.                                 Автор: Перчиц С.Н.   *

'*************************************************************************

'

pi = 3.14159

xc = 200

yc = 200

rb = 200

du = pi / rb

dub = 2 * pi / 24

c = 14

SCREEN 12

FOR ub = 0 TO 2 * pi STEP dub

   FOR ddub = 0 TO dub / 3 STEP dub / 20

      u = ub + ddub

      FOR r = 0 TO rb

         u = u + du

         x = r * COS(u)

         y = r * SIN(u)

         PSET (xc + x, yc + y), c

'         PSET (xc + x, yc - y), c

      NEXT r

   NEXT ddub

NEXT ub

'*************************************************************************

'*  GF_PL_TN      Рисование  "плетенки" с тенью                          *

'*  --------                                                             *

'*  Источник: С.В.Филичев "Занимательный Basic в задачах". Издат. ЭКОМ   *

'*  --------                                                             *

'*   Август 1999 г.                                 Автор: Перчиц С.Н.   *

'*************************************************************************

'

pi = 3.14159

xc = 160

yc = 160

rb = 150

du = pi / rb

dub = 2 * pi / 24

c = 10

c1 = 6

c2 = 7

SCREEN 12

FOR ub = 0 TO 2 * pi STEP dub

   FOR ddub = 0 TO dub / 3 STEP dub / 20

      u = ub + ddub

      FOR r = 0 TO rb

         u = u + du

         x = r * COS(u)

         y = r * SIN(u)

         PSET (xc + x, yc + y), c

         PSET (xc + x, yc - y), c

      NEXT r

   NEXT ddub

NEXT ub

xs = 200

ys = 100

m = 1

FOR y = yc - rb TO yc + rb

   FOR x = xc - rb TO xc + rb

      xt = m * x + xs

      yt = m * y + ys

      IF (POINT(x, y) = c) AND (POINT(xt, yt) <> c) THEN PSET (xt, yt), c1

   NEXT x

NEXT y

xs = 50

ys = 150

m = 1

FOR y = yc - rb TO yc + rb

   FOR x = xc - rb TO xc + rb

      xt = m * x + xs

      yt = m * y + ys

      IF (POINT(x, y) = c) AND (POINT(xt, yt) <> c) AND (POINT(xt, yt) <> c1) THEN PSET (xt, yt), c2

   NEXT x

NEXT y

'*************************************************************************

'*  GF_YANIN      Рисование знака "ян-инь"                               *

'*  --------                                                             *

'*  Источник: С.В.Филичев "Занимательный Basic в задачах". Издат. ЭКОМ   *

'*  --------                                                             *

'*   Август 1999 г.                                 Автор: Перчиц С.Н.   *

'*************************************************************************

'

SCREEN 12

pi = 3.14159

pi2 = pi + pi

du = pi / 60

rb = 50

rm = rb * 3 / 8

xc = 320

yc = 240

PAINT (1, 1), 7

DO

   u = u + du

   IF u > pi2 THEN u = u - pi2

   x = rb * COS(u)

   y = rb * SIN(u)

   xl = xc - x

   yl = yc - y

   xr = xc + x

   yr = yc + y

   FOR r = 0 TO rm

      CIRCLE (xr, yr), r, 15

      CIRCLE (xl, yl), r, 0

   NEXT r

   FOR r = r TO rb

      CIRCLE (xr, yr), r, 0

      CIRCLE (xl, yl), r, 15

   NEXT r

LOOP WHILE INKEY$ = ""